% BibTeX `apalikenl' bibliography style (version 0.99a, 8-Dec-10), adapted from
% the `alpha' style, version 0.99a; for BibTeX version 0.99a.
%
% Copyright (C) 1988, 2010 Oren Patashnik.
% Unlimited copying and redistribution of this file are permitted as long as
% it is unmodified.  Modifications (and redistribution of modified versions)
% are also permitted, but only if the resulting file is renamed.
%
% Differences between this style and `alpha' are generally heralded by a `%'.
% The file btxbst.doc has the documentation for alpha.bst.
%
% This style should be used with the `apalike' LaTeX style (apalike.sty).
% \cite's come out like "(Jones, 1986)" in the text but there are no labels
% in the bibliography, and something like "(1986)" comes out immediately
% after the author.  Author (and editor) names appear as last name, comma,
% initials.  A `year' field is required for every entry, and so is either
% an author (or in some cases, an editor) field or a key field.
%
% Editorial note:
% Many journals require a style like `apalike', but I strongly, strongly,
% strongly recommend that you not use it if you have a choice---use something
% like `plain' instead.  Mary-Claire van Leunen (A Handbook for Scholars,
% Knopf, 1979) argues convincingly that a style like `plain' encourages better
% writing than one like `apalike'.  Furthermore the strongest arguments for
% using an author-date style like `apalike'---that it's "the most practical"
% (The Chicago Manual of Style, University of Chicago Press, thirteenth
% edition, 1982, pages 400--401)---fall flat on their face with the new
% computer-typesetting technology.  For instance page 401 anachronistically
% states "The chief disadvantage of [a style like `plain'] is that additions
% or deletions cannot be made after the manuscript is typed without changing
% numbers in both text references and list."  LaTeX sidesteps the disadvantage.
%
% History:
%   15-sep-86  (OP)  Original version by Oren Patashnik, ideas from Susan King.
%   10-nov-86  (OP)  Truncated the sort.key$ string to the correct length
%                    in bib.sort.order to eliminate error message.
%   24-jan-88  (OP)  Updated for BibTeX version 0.99a, from alpha.bst 0.99a;
%                    apalike now sorts by author, then year, then title;
%                    THIS `apalike' VERSION DOES NOT WORK WITH BIBTEX 0.98i.
%    8-dec-10  (OP)  Still version 0.99a, as the code itself was unchanged;
%                    this release clarified the license.

ENTRY
  { address
    author
    booktitle
    chapter
    edition
    editor
    howpublished
    institution
    journal
    key
%    month              not used in apalike
    note
    number
    organization
    pages
    publisher
    school
    series
    title
    type
    volume
    year
  }
  {}
  { label extra.label sort.label }

INTEGERS { output.state before.all mid.sentence after.sentence after.block }

FUNCTION {init.state.consts}
{ #0 'before.all :=
  #1 'mid.sentence :=
  #2 'after.sentence :=
  #3 'after.block :=
}

STRINGS { s t }

FUNCTION {output.nonnull}
{ 's :=
  output.state mid.sentence =
    { ", " * write$ }
    { output.state after.block =
        { add.period$ write$
          newline$
          "\newblock " write$
        }
        { output.state before.all =
            'write$
            { add.period$ " " * write$ }
          if$
        }
      if$
      mid.sentence 'output.state :=
    }
  if$
  s
}

FUNCTION {output}
{ duplicate$ empty$
    'pop$
    'output.nonnull
  if$
}

FUNCTION {output.check}
{ 't :=
  duplicate$ empty$
    { pop$ "empty " t * " in " * cite$ * warning$ }
    'output.nonnull
  if$
}

%                                       apalike needs this function because
%                                       the year has special punctuation;
%                                       apalike ignores the month
FUNCTION {output.year.check}
{ year empty$
    { "empty year in " cite$ * warning$ }
    { write$
      " (" year * extra.label * ")" *
      mid.sentence 'output.state :=
    }
  if$
}

FUNCTION {output.bibitem}
{ newline$
  "\bibitem[" write$
  label write$
  "]{" write$
  cite$ write$
  "}" write$
  newline$
  ""
  before.all 'output.state :=
}

FUNCTION {fin.entry}
{ add.period$
  write$
  newline$
}

FUNCTION {new.block}
{ output.state before.all =
    'skip$
    { after.block 'output.state := }
  if$
}

FUNCTION {new.sentence}
{ output.state after.block =
    'skip$
    { output.state before.all =
        'skip$
        { after.sentence 'output.state := }
      if$
    }
  if$
}

FUNCTION {not}
{   { #0 }
    { #1 }
  if$
}

FUNCTION {and}
{   'skip$
    { pop$ #0 }
  if$
}

FUNCTION {or}
{   { pop$ #1 }
    'skip$
  if$
}

FUNCTION {new.block.checka}
{ empty$
    'skip$
    'new.block
  if$
}

FUNCTION {new.block.checkb}
{ empty$
  swap$ empty$
  and
    'skip$
    'new.block
  if$
}

FUNCTION {new.sentence.checka}
{ empty$
    'skip$
    'new.sentence
  if$
}

FUNCTION {new.sentence.checkb}
{ empty$
  swap$ empty$
  and
    'skip$
    'new.sentence
  if$
}

FUNCTION {field.or.null}
{ duplicate$ empty$
    { pop$ "" }
    'skip$
  if$
}

FUNCTION {emphasize}
{ duplicate$ empty$
    { pop$ "" }
    { "{\em " swap$ * "}" * }
  if$
}

INTEGERS { nameptr namesleft numnames }

FUNCTION {format.names}
{ 's :=
  #1 'nameptr :=
  s num.names$ 'numnames :=
  numnames 'namesleft :=
    { namesleft #0 > }

    { s nameptr "{ff~}{vv~}{ll}{, jj}" format.name$ 't :=

      nameptr #1 >                  % in de referentie wordt de volledige naam
    { namesleft #1 >                % afgedrukt: "J.H. van Dale"  (WS)
        { ", " * t * }
        { numnames #2 >
         { "," * }
         'skip$
          if$
          t "others" =
         { " {\em ~et~al.}" * }
         { " en " * t * }           % hier wordt een tussenvoegsel
          if$                       % tussen auteursnamen gemaakt   (WS)
            }
          if$
        }
        't
      if$
      nameptr #1 + 'nameptr :=
      namesleft #1 - 'namesleft :=
    }
  while$
}

FUNCTION {format.authors}
{ author empty$
    { "" }
    { author format.names }
  if$
}

FUNCTION {format.key}                   % this function is just for apalike
{ empty$
    { key field.or.null }
    { "" }
  if$
}

% Een editor heet in het Nedelands redacteur, maar het is gebruikelijk
% dit aan te geven met ``redactie''. (230492).

FUNCTION {format.editors}
{ editor empty$
    { "" }
    {  editor format.names
       ", redactie" *
    }
  if$
}

% Sommige boeken hebben behalve een auteur ook een redacteur; m.n.
% wanneer de tekst van een ouder werk opnieuw wordt uitgegeven. Voor
% dit soort gevallen is format.editortoo:
%
FUNCTION {format.editorstoo}
{ editor empty$
    { "" }
    {  " bezorgd door " editor format.names *
    }
  if$
}

FUNCTION {format.title}
{ title empty$
    { "" }
    { title "t" change.case$ }
  if$
}

FUNCTION {n.dashify}
{ 't :=
  ""
    { t empty$ not }
    { t #1 #1 substring$ "-" =
        { t #1 #2 substring$ "--" = not
            { "--" *
              t #2 global.max$ substring$ 't :=
            }
            {   { t #1 #1 substring$ "-" = }
                { "-" *
                  t #2 global.max$ substring$ 't :=
                }
              while$
            }
          if$
        }
        { t #1 #1 substring$ *
          t #2 global.max$ substring$ 't :=
        }
      if$
    }
  while$
}

FUNCTION {format.btitle}
{ title emphasize
}

FUNCTION {tie.or.space.connect}
{ duplicate$ text.length$ #3 <
    { "~" }
    { " " }
  if$
  swap$ * *
}

FUNCTION {either.or.check}
{ empty$
    'pop$
    { "can't use both " swap$ * " fields in " * cite$ * warning$ }
  if$
}

FUNCTION {format.bvolume}                            % in het Nederlands (WS)
{ volume empty$
    { "" }
    { series empty$
      { " deel"  }                                  % zonder komma (WS;220492)
      { " "  series emphasize * ", deel" * }
      if$
      volume tie.or.space.connect
    }
  if$
}

FUNCTION {format.number.series}                      % in het Nederlands (WS)
{ volume empty$
    { number empty$
        { series field.or.null }
        { series empty$
            { "there's a number but no series in " cite$ * warning$ }
            { series number tie.or.space.connect }
          if$
        }
      if$
    }
    { "" }
  if$
}

FUNCTION {format.edition}                             % in het Nederlands (WS)
{ edition empty$
    { "" }
    { edition "1" =
        { "Eerste" }
        { edition "2" =
            { "Tweede" }
            { edition "3" =
                { "Derde" }
                { edition "$^{\rm e}$ " * }
                if$
            }
            if$
        }
        if$
        output.state mid.sentence =
            { "l" change.case$ " druk" * }
            { "t" change.case$ " druk" * }
            if$
    }
    if$
}

INTEGERS { multiresult }

FUNCTION {multi.page.check}
{ 't :=
  #0 'multiresult :=
    { multiresult not
      t empty$ not
      and
    }
    { t #1 #1 substring$
      duplicate$ "-" =
      swap$ duplicate$ "," =
      swap$ "+" =
      or or
        { #1 'multiresult := }
        { t #2 global.max$ substring$ 't := }
      if$
    }
  while$
  multiresult
}

FUNCTION {format.pages}
{ pages empty$
    { "" }
    { pages multi.page.check
        { "pp." pages n.dashify tie.or.space.connect }
        { "p." pages tie.or.space.connect }
      if$
    }
  if$
}

FUNCTION {format.vol.num.pages}
{ volume field.or.null
  number empty$
    'skip$
    { "(" number * ")" * *
      volume empty$
        { "there's a number but no volume in " cite$ * warning$ }
        'skip$
      if$
    }
  if$
  pages empty$
    'skip$
    { duplicate$ empty$
        { pop$ format.pages }
        { ", pp. " * pages n.dashify * }
      if$
    }
  if$
}

FUNCTION {format.chapter.pages}                       % in het Nederlands (WS)
{ chapter empty$
    'format.pages
    { type empty$
        { output.state mid.sentence =
          { "hoofdstuk" }
          { "Hoofdstuk" }
          if$
         }
        { type "l" change.case$ }
      if$
      chapter tie.or.space.connect
      pages empty$
        'skip$
        { ", " * format.pages * }
      if$
    }
  if$
}

FUNCTION {format.in.ed.booktitle}                     % in het Nederlands (WS)
{ booktitle empty$                                    %
    { "" }
    { editor empty$
      { output.state mid.sentence =
        { "in " booktitle emphasize * }
        { "In " booktitle emphasize * }
        if$ }
      { output.state mid.sentence =
        { "in " booktitle emphasize * ", " * format.editors * }
        { "In " booktitle emphasize * ", " * format.editors * }
        if$ }
      if$
    }
  if$
}

FUNCTION {format.thesis.type}
{ type empty$
    'skip$
    { pop$
      type "t" change.case$
    }
  if$
}

FUNCTION {format.preprint.number}
{ type empty$
    { "Preprint" }
    'type
  if$
  number empty$
    { "t" change.case$ }
    { number tie.or.space.connect }
  if$
}

FUNCTION {format.tr.number}
{ type empty$
    { "Technical Report" }
    'type
  if$
  number empty$
    { "t" change.case$ }
    { number tie.or.space.connect }
  if$
}

FUNCTION {format.article.crossref}
{ key empty$
    { journal empty$
    { "need key or journal for " cite$ * " to crossref " * crossref *
      warning$
      ""
    }
    { "In {\em " journal * "\/}" * }
      if$
    }
    { "In " key * }
  if$
  " \cite{" * crossref * "}" *
}

FUNCTION {format.book.crossref}
{ volume empty$
    { "empty volume in " cite$ * "'s crossref of " * crossref * warning$
      "In "
    }
    { "Volume" volume tie.or.space.connect
      " of " *
    }
  if$
  editor empty$
  editor field.or.null author field.or.null =
  or
    { key empty$
    { series empty$
        { "need editor, key, or series for " cite$ * " to crossref " *
          crossref * warning$
          "" *
        }
        { "{\em " * series * "\/}" * }
      if$
    }
    { key * }
      if$
     " \cite{" * crossref * "}" *
    }
    { " \citeasnoun{" * crossref * "}" * }
  if$
}

FUNCTION {institution.or.organization.output}
{institution empty$
 {organization empty$
  { "Both organization and institution are missing in " cite$ * warning$ }
  { organization output }
  if$
 }
 {institution output}
if$
}

% v2.5 (1-6-93) crossreferencing changed: uses \citeasnoun when possible
FUNCTION {format.incoll.inproc.crossref}
{ editor empty$
  editor field.or.null author field.or.null =
  or
    { key empty$
    { booktitle empty$
        { "need editor, key, or booktitle for " cite$ * " to crossref " *
          crossref * warning$
          ""
        }
        { "In {\em " booktitle * "\/}" * }
      if$
    }
    { "In " key * }
      if$
    " \cite{" * crossref * "}" *
    }
    { "In \citeasnoun{" crossref * "}" * }
  if$

}

FUNCTION {article}
{ output.bibitem
  format.authors "author" output.check
  author format.key output                              % special for
  output.year.check                                     % apalike
  new.block
  format.title "title" output.check
  new.block
  crossref missing$
    { journal emphasize "journal" output.check
      format.vol.num.pages output
    }
    { format.article.crossref output.nonnull
      format.pages output
    }
  if$
  new.block
  note output
  fin.entry
}

FUNCTION {book}
{ output.bibitem
  author empty$
    { format.editors "author and editor" output.check
      editor format.key output
    }
    { format.authors output.nonnull
      crossref missing$
        { "author and editor" editor either.or.check }
        'skip$
      if$
    }
  if$
  output.year.check                             % special for apalike
  new.block
  format.btitle "title" output.check
  crossref missing$
    { format.bvolume output
      new.block
      format.number.series output
      new.sentence
      publisher "publisher" output.check
      address output
    }
    { new.block
      format.book.crossref output.nonnull
    }
  if$
  format.edition output
  new.block
  note output
  fin.entry
}

FUNCTION {booklet}
{ output.bibitem
  format.authors output
  author format.key output                              % special for
  output.year.check                                     % apalike
  new.block
  format.title "title" output.check
  new.block
  howpublished output
  address output
  new.block
  note output
  fin.entry
}

FUNCTION {inbook}
{ output.bibitem
  author empty$
    { format.editors "author and editor" output.check
      editor format.key output
    }
    { format.authors output.nonnull
      crossref missing$
        { "author and editor" editor either.or.check }
        'skip$
      if$
    }
  if$
  output.year.check                             % special for apalike
  new.block
  format.btitle "title" output.check
  crossref missing$
    { format.bvolume output
      format.chapter.pages "chapter and pages" output.check
      new.block
      format.number.series output
      new.sentence
      publisher "publisher" output.check
      address output
    }
    { format.chapter.pages "chapter and pages" output.check
      new.block
      format.book.crossref output.nonnull
    }
  if$
  format.edition output
  new.block
  note output
  fin.entry
}

FUNCTION {incollection}
{ output.bibitem
  format.authors "author" output.check
  author format.key output                              % special for
  output.year.check                                     % apalike
  new.block
  format.title "title" output.check
  new.block
  crossref missing$
    { format.in.ed.booktitle "booktitle" output.check
      format.bvolume output
      format.number.series output
      format.chapter.pages output
      new.sentence
      publisher "publisher" output.check
      address output
      format.edition output
    }
    { format.incoll.inproc.crossref output.nonnull
      format.chapter.pages output
    }
  if$
  new.block
  note output
  fin.entry
}

FUNCTION {inproceedings}
{ output.bibitem
  format.authors "author" output.check
  author format.key output                              % special for
  output.year.check                                     % apalike
  new.block
  format.title "title" output.check
  new.block
  crossref missing$
    { format.in.ed.booktitle "booktitle" output.check
      format.bvolume output
      format.number.series output
      format.pages output
      address output                                    % for apalike
      new.sentence                                      % there's no year
      organization output                               % here so things
      publisher output                                  % are simpler
    }
    { format.incoll.inproc.crossref output.nonnull
      format.pages output
    }
  if$
  new.block
  note output
  fin.entry
}

FUNCTION {conference} { inproceedings }

FUNCTION {manual}
{ output.bibitem
  format.authors output
  author format.key output                              % special for
  output.year.check                                     % apalike
  new.block
  format.btitle "title" output.check
  organization address new.block.checkb
  organization output
  address output
  format.edition output
  new.block
  note output
  fin.entry
}

FUNCTION {mastersthesis}                % doctoraalscriptie (WS)
{ output.bibitem
  format.authors "author" output.check
  author format.key output                              % special for
  output.year.check                                     % apalike
  new.block
  format.title "title" output.check
  new.block
  "Masterscriptie" format.thesis.type output.nonnull
  school "school" output.check
  address output
  new.block
  note output
  fin.entry
}

FUNCTION {misc}
{ output.bibitem
  format.authors output
  author format.key output                              % special for
  output.year.check                                     % apalike
  new.block
  format.title output
  new.block
  howpublished output
  new.block
  note output
  fin.entry
}

FUNCTION {phdthesis}                                     % proefschrift (WS)
{ output.bibitem
  format.authors "author" output.check
  author format.key output                              % special for
  output.year.check                                     % apalike
  new.block
  format.btitle "title" output.check
  new.block
  "Dissertatie" format.thesis.type output.nonnull
  school "school" output.check
  address output
  new.block
  note output
  fin.entry
}

FUNCTION {proceedings}
{ output.bibitem
  format.editors output
  editor format.key output                              % special for
  output.year.check                                     % apalike
  new.block
  format.btitle "title" output.check
  format.bvolume output
  format.number.series output
  address output                                % for apalike
  new.sentence                                  % we always output
  organization output                           % a nonempty organization
  publisher output                              % here
  new.block
  note output
  fin.entry
}

FUNCTION {techreport}
{ output.bibitem
  format.authors "author" output.check
  author format.key output                              % special for
  output.year.check                                     % apalike
  new.block
  format.title "title" output.check
  new.block
  format.tr.number output.nonnull
  institution "institution" output.check
  address output
  new.block
  note output
  fin.entry
}

FUNCTION {unpublished}
{ output.bibitem
  format.authors "author" output.check
  author format.key output                              % special for
  output.year.check                                     % apalike
  new.block
  format.title "title" output.check
  new.block
  note "note" output.check
  fin.entry
}

FUNCTION {default.type} { misc }


%
MACRO {tbp}		{"verschijnt"}

% De namen van de maanden in het Nederlands
%
MACRO {jan}		{"januari"}
MACRO {feb}		{"februari"}
MACRO {mar}		{"maart"}
MACRO {apr}		{"april"}
MACRO {may}		{"mei"}
MACRO {jun}		{"juni"}
MACRO {jul}		{"juli"}
MACRO {aug}		{"augustus"}
MACRO {sep}		{"september"}
MACRO {oct}		{"oktober"}
MACRO {nov}		{"november"}
MACRO {dec}		{"december"}

% De Nederlanse universiteiten
%
MACRO {KUB}		{"Katholieke Universiteit Brabant"}
MACRO {KUN}		{"Katholieke Universiteit Nijmegen"}
MACRO {KUT}		{"Katholieke Universiteit Twente"}
MACRO {LUW}		{"Landbouwuniversiteit Wageningen"}
MACRO {RL}		{"Rijksuniversiteit Limburg"}
MACRO {RUG}		{"Rijksuniversiteit te Groningen"}
MACRO {RUL}		{"Rijksuniversiteit te Leiden"}
MACRO {RUU}		{"Rijksuniversiteit te Utrecht"}
MACRO {TUD}		{"Technische Universiteit Delft"}
MACRO {TUE}		{"Technische Universiteit Eindhoven"}
MACRO {TUT}		{"Universiteit Twente"}
MACRO {EUR}		{"Erasmusuniversiteit Rotterdam"}
MACRO {UvA}		{"Universiteit van Amsterdam"}
MACRO {VU}		{"Vrije Universiteit"}

% Een aantal uitgeverijen
%
MACRO {AcS}		{"Academic Service"}
MACRO {APS}		{"American Philosophical Society"}
MACRO {Bal}		{"Balans"}
MACRO {BoP}		{"The Boydell Press"}
MACRO {Brink}		{"C.L. Brinkman"}
MACRO {Cas}		{"Cassell \& Co"}
MACRO {ClP}		{"Clarendon Press"}
MACRO {Cou}		{"Coutinho"}
MACRO {CUP}		{"Cambridge University Press"}
MACRO {DMU}		{"Dutch Media Uitgevers"}
MACRO {DUM}		{"Delftse Uitgevers Maatschappij"}
MACRO {Goor}		{"G.B. van Goor Zonen's Uitgeversmaatschappij"}
MACRO {Gorc}		{"Van Gorcum \& Comp. B.V."}
MACRO {HUP}		{"Harvard University Press"}
MACRO {JWS}		{"John Wiley \& Sons Ltd"}
MACRO {KB}		{"Koninklijke Bibliotheek"}
MACRO {KNAW}		{"Koninklijke Nederlandse Akademie van Wetenschappen"}
MACRO {MIT}		{"MIT Press"}
MACRO {NeT}		{"Nederlandse Taalunie"}
MACRO {NGN}		{"National Geographic Nederland"}
MACRO {Nij}		{"Martinus Nijhoff"}
MACRO {NSF}		{"National Science Foundation"}
MACRO {OUP}		{"Oxford University Press"}
MACRO {PEd}		{"Pearson Education, Inc."}
MACRO {PrH}		{"Prentice-Hall Inc."}
MACRO {SAS}		{"Center for History of Science at the Royal Swedish Academy of Sciences"}
MACRO {ScAmL}		{"Scientific American Library"}
MACRO {Sdu}		{"Sdu Uitgevers"}
MACRO {Sijt}		{"A.W. Sijthoff"}
MACRO {SvJ}		{"School voor de Journalistiek"}
MACRO {TNS}		{"Thomas Nelson and Sons LTD"}
MACRO {UCP}		{"University of California Press"}
MACRO {WN}		{"Wolters-Noordhoff"}
MACRO {WSP}		{"World Scientific Publishing Co."}

% Een aantal tijdschriften
%
MACRO {AA}		{"Astronomy \& Astrophysics"}
MACRO {AAS}		{"American Astronomical Society"}
MACRO {acmcs}		{"ACM Computing Surveys"}
MACRO {AcP}		{"Acta Physica"}
MACRO {AcPA}		{"Acta Physica Austriaca"}
MACRO {AcPP}		{"Acta Physica Polonica"}
MACRO {acta}		{"Acta Informatica"}
MACRO {ADNDT}		{"Atomic Data and Nuclear Data Tables"}
MACRO {AdP}		{"Advances in Physics"}
MACRO {AdNP}		{"Advances in Nuclear Physics"}
MACRO {AIR}		{"Annals of Improbable Research"}
MACRO {AmJP}		{"American Journal of Physics"}
MACRO {AmS}		{"American Scientist"}
MACRO {AnPDu}		{"Annalen der Physik (Leipzig)"}
MACRO {AnPFr}		{"Annales de Physique (Paris)"}
MACRO {AnPNY}		{"Annals of Physics (NY)"}
MACRO {APA}		{"American Psychological Association"}
MACRO {ARD}		{"Annals of the Rheumatic Diseases"}
MACRO {ARevNS}		{"Annual Review of Nuclear Science"}
MACRO {Arts}		{"The Journal of the Sydney University Arts Association"}
MACRO {AsJ}		{"Astrophysical Journal"}
MACRO {ASP}		{"Arabic Sciences and Philosophy"}
MACRO {AusJP}		{"Australian Journal of Physics"}
MACRO {AV}		{"Ad Valvas"}
MACRO {BacR}		{"Bacteriological Reviews"}
MACRO {BMGN}		{"BMGN -- Low Countries Historical Review"}
MACRO {cacm}		{"Communications of the ACM"}
MACRO {CanJP}		{"Canadian Journal Physics"}
MACRO {CM}		{"Chemisch magazine"}
MACRO {CPC}		{"Computer Physics Communications"}
MACRO {DeI}		{"Delft integraal"}
MACRO {EJP}		{"European Journal of Physics"}
MACRO {EPL}		{"Europhysics Letters"}
MACRO {FBS}		{"Few Body Systems"}
MACRO {FBSSup}		{"Few Body Systems Supplement"}
MACRO {FortP}		{"Fortschritte der Physik"}
MACRO {GRG}		{"General Relativity and Gravitation"}
MACRO {Gro}		{"Groniek"}
MACRO {HePA}		{"Helvetica Physica Acta"}
MACRO {HIJPP}		{"The Harvard International Journal of Press/Politics"}
MACRO {HiM}		{"Historia Mathematica"}
MACRO {ibmjrd}		{"IBM Journal of Research and Development"}
MACRO {ibmsj}		{"IBM Systems Journal"}
MACRO {IEEE}		{"IEEE Transactions"}
MACRO {IEEEAPM}		{"IEEE Antennas and Propagation Magazine"}
MACRO {IEEEP}		{"Proceedings of the IEEE"}
MACRO {ieeese}		{"IEEE Transactions on Software Engineering"}
MACRO {ieeetc}		{"IEEE Transactions on Computers"}
MACRO {ieeetcad}	{"IEEE Transactions on Computer-Aided Design of Integrated Circuits"}
MACRO {ieeetpc}		{"IEEE Transactions on Professional Communication"}
MACRO {IJMP}		{"International Journal of Modern Physics"}
MACRO {ipl}		{"Information Processing Letters"}
MACRO {Isis}		{"Isis"}
MACRO {jacm}		{"Journal of the ACM"}
MACRO {JAHH}		{"Journal of Astronomical History and Heritage"}
MACRO {JaFi}		{"{\cyr {\Ja}derna\ja\ Fizika}"}
MACRO {jcss}		{"Journal of Computer and System Sciences"}
MACRO {JEG}		{"Journal of Economic Growth"}
MACRO {JETP}		{"JETP"}
MACRO {JETPL}		{"JETP Letters"}
MACRO {JHA}		{"Journal for the History of Astronomy"}
MACRO {JMP}		{"Journal of Mathematical Physics"}
MACRO {JoC}		{"Journal of Communication"}
MACRO {JoN}		{"Journal of Navigation"}
MACRO {JOSA}		{"Journal of the Optical Society of America"}
MACRO {JPFr}		{"Journal de Physique (Paris)"}
MACRO {JP}		{"Journal of Physics"}
MACRO {JPSJ}		{"Journal of the Physical Society of Japan"}
MACRO {JPSJSup}		{"Journal of the Physical Society of Japan Supplement"}
MACRO {KuL}		{"Kultuurleven"}
MACRO {LA}		{"Linguistica Antverpiensia"}
MACRO {Leid}		{"Leidschrift"}
MACRO {LRR}		{"Living Reviews in Relativity"}
MACRO {MPL}		{"Modern Physics Letters"}
MACRO {Nat}		{"Nature"}
MACRO {NAW}		{"Nieuw Archief voor Wiskunde"}
MACRO {NT}		{"Natuur \& Techniek"}
MACRO {NCim}		{"Il Nuovo Cimento"}
MACRO {NDS}		{"Nuclear Data Sheets"}
MACRO {NTN}		{"Nederlands Tijdschrift voor Natuurkunde"}
MACRO {NvN}		{"Nederlands van Nu"}
MACRO {NP}		{"Nuclear Physics"}
MACRO {NPSup}		{"Nuclear Physics Supplements"}
MACRO {NTvN}		{"Nederlands Tijdschrift voor Natuurkunde"}
MACRO {OT}		{"Onze Taal"}
MACRO {Phy}		{"Physica"}
MACRO {PL}		{"Physics Letters"}
MACRO {PRSLon}		{"Proceedings of the Royal Society of London"}
MACRO {PR}		{"Physical Review"}
MACRO {PRL}		{"Physical Review Letters"}
MACRO {PRep}		{"Physics Reports"}
MACRO {PScr}		{"Physica Scripta"}
MACRO {PToday}		{"Physics Today"}
MACRO {PTP}		{"Progress of Theoretical Physics"}
MACRO {PTRSL}		{"Philosophical Transactions of the Royal Society of London"}
MACRO {PTRSLA}		{"Philosophical Transactions of the Royal Society of London A"}
MACRO {PUS}		{"Public Understanding of Science"}
MACRO {QJRAS}		{"Quarterly Journal of the Royal Astronomical Society"}
MACRO {RMP}		{"Reviews of Modern Physics"}
MACRO {RPP}		{"Reports of Progress in Physics"}
MACRO {Rv}		{"Ruimtevaart"}
MACRO {ScAm}		{"Scientific American"}
MACRO {Sci}		{"The Scientist"}
MACRO {SCom}		{"Science Communications"}
MACRO {scp}		{"Science of Computer Programming"}
MACRO {sicomp}		{"SIAM Journal on Computing"}
MACRO {SovJNP}		{"Soviet Journal of Nuclear Physics"}
MACRO {SovJPN}		{"Soviet Journal of Particles and Nuclei"}
MACRO {SovPDo}		{"Soviet Physics Doklady"}
MACRO {SovPUs}		{"Soviet Physics Uspekhi"}
MACRO {SPAW}		{"Sitzungsberichte der Preussische Akademie der Wissenschaften"}
MACRO {Spec}		{"Spectroscopy"}
MACRO {SSR}		{"Space Science Reviews"}
MACRO {SSRC}		{"Social Science Research Council"}
MACRO {STS}		{"Bulletin of Science, Technology and Social Affairs"}
MACRO {Stud}		{"Studium. Tijdschrift voor Wetenschaps- en Universiteitsgeschiedenis"}
MACRO {SWA}		{"Stiching Weten Amsterdam"}
MACRO {TGGNWT}		{"Tijdschrift voor de geschiedenis der geneeskunde, natuurwetenschappen, wiskunde en techniek"}
MACRO {tocs}		{"ACM Transactions on Computer Systems"}
MACRO {tods}		{"ACM Transactions on Database Systems"}
MACRO {tog}		{"ACM Transactions on Graphics"}
MACRO {toms}		{"ACM Transactions on Mathematical Software"}
MACRO {toois}		{"ACM Transactions on Office Information Systems"}
MACRO {toplas}		{"ACM Transactions on Programming Languages and Systems"}
MACRO {tcs}		{"Theoretical Computer Science"}
MACRO {TSEG}		{"Tijdschrift voor Sociale en Economische Geschiedenis"}
MACRO {TWTS}		{"Tijdschrift voor wetenschap, technologie en samenleving"}
MACRO {TvC}		{"Tijdschrift voor Communicatiewetenschap"}
MACRO {ZfMP}		{"Zeitschrift f{\H{u}}r Mathematik und Physik"}
MACRO {ZfN}		{"Zeitschrift f{\H{u}}r Naturforschung"}
MACRO {ZfP}		{"Zeitschrift f{\H{u}}r Physik"}

READ

FUNCTION {sortify}
{ purify$
  "l" change.case$
}

INTEGERS { numberlen numberzero}

FUNCTION {numsortify}
{ purify$
  "l" change.case$
  's :=
  #1 'numberlen :=
  { s numberlen #1 substring$ "1" =
    s numberlen #1 substring$ "2" =
    s numberlen #1 substring$ "3" =
    s numberlen #1 substring$ "4" =
    s numberlen #1 substring$ "5" =
    s numberlen #1 substring$ "6" =
    s numberlen #1 substring$ "7" =
    s numberlen #1 substring$ "8" =
    s numberlen #1 substring$ "9" =
    s numberlen #1 substring$ "0" =
    or or or or or or or or or    }
  { numberlen #1 + 'numberlen :=  }
  while$
  #6 numberlen -  'numberzero :=
  "000000" #1 numberzero substring$
  s *
}
INTEGERS { len }

FUNCTION {chop.word}
{ 's :=
  'len :=
  s #1 len substring$ =
    { s len #1 + global.max$ substring$ }
    's
  if$
}

%                       There are three apalike cases: one person (Jones),
%                       two (Jones and de~Bruijn), and more (Jones et~al.).
%                       This function is much like format.crossref.editors.
%
FUNCTION {format.lab.names}
{ 's :=
  s #1 "{vv~}{ll}" format.name$
  s num.names$ duplicate$
  #2 >
    { pop$ " et~al." * }
    { #2 <
        'skip$
        { s #2 "{ff }{vv }{ll}{ jj}" format.name$ "others" =
            { " et~al." * }
            { " en " * s #2 "{vv~}{ll}" format.name$ * }
          if$
        }
      if$
    }
  if$
}

FUNCTION {author.key.label}
{ author empty$
    { key empty$
        { cite$ #1 #3 substring$ }
        'key                                    % apalike uses the whole key
      if$
    }
    { author format.lab.names }
  if$
}

FUNCTION {author.editor.key.label}
{ author empty$
    { editor empty$
        { key empty$
            { cite$ #1 #3 substring$ }
            'key                                % apalike uses the whole key
          if$
        }
        { editor format.lab.names }
      if$
    }
    { author format.lab.names }
  if$
}

FUNCTION {editor.key.label}
{ editor empty$
    { key empty$
        { cite$ #1 #3 substring$ }
        'key                    % apalike uses the whole key, no organization
      if$
    }
    { editor format.lab.names }
  if$
}

FUNCTION {calc.label}
{ type$ "book" =
  type$ "inbook" =
  or
    'author.editor.key.label
    { type$ "proceedings" =
        'editor.key.label                       % apalike ignores organization
        'author.key.label                       % for labeling and sorting
      if$
    }
  if$
  ", "                                                  % these three lines are
  *                                                     % for apalike, which
  year field.or.null purify$ #-1 #4 substring$          % uses all four digits
  *
  'label :=
}

FUNCTION {sort.format.names}
{ 's :=
  #1 'nameptr :=
  ""
  s num.names$ 'numnames :=
  numnames 'namesleft :=
    { namesleft #0 > }
    { nameptr #1 >
    { "         " * }
    'skip$
      if$                 % het sorteerlabel begrijpt Nederlandse namen
                          % b.v  "Dale van JH"   (WS)
      s nameptr "{ll{ }}{vv{ }}{  f{ }}{  jj{ }}" format.name$ 't :=
      nameptr numnames = t "others" = and
    { "{\em~et~al}" * }
    { t sortify * }
      if$
      nameptr #1 + 'nameptr :=
      namesleft #1 - 'namesleft :=
    }
  while$
}

FUNCTION {sort.format.title}
{ 't :=
  "De " #3                                % titels worden gesorteerd
   "Een " #4                              % op het lidwoord na  (WS)
    "A " #2                               % verbeterd (2-11-93)
     "An " #3
      "The " #4 t chop.word
              chop.word
          chop.word
      chop.word
  chop.word
  sortify
  #1 global.max$ substring$
}

FUNCTION {author.sort}
{ author empty$
    { key empty$
        { "to sort, need author or key in " cite$ * warning$
          ""
        }
        { key sortify }
      if$
    }
    { author sort.format.names }
  if$
}

FUNCTION {author.editor.sort}
{ author empty$
    { editor empty$
        { key empty$
            { "to sort, need author, editor, or key in " cite$ * warning$
              ""
            }
            { key sortify }
          if$
        }
        { editor sort.format.names }
      if$
    }
    { author sort.format.names }
  if$
}

FUNCTION {editor.sort}
{ editor empty$
    { key empty$
        { "to sort, need editor or key in " cite$ * warning$
          ""
        }
        { key sortify }
      if$
    }
    { editor sort.format.names }
  if$
}


%                       apalike uses two sorting passes; the first one sets the
%                       labels so that the `a's, `b's, etc. can be computed;
%                       the second pass puts the references in "correct" order.
%                       The presort function is for the first pass. It computes
%                       label, sort.label, and title, and then concatenates.
FUNCTION {presort}
{ calc.label
  label sortify
  "    "
  *
  type$ "book" =
  type$ "inbook" =
  or
    'author.editor.sort
    { type$ "proceedings" =
        'editor.sort
        'author.sort
      if$
    }
  if$
  #1 entry.max$ substring$      % for
  'sort.label :=                % apalike
  sort.label                    % style
*
  "    "
  *
  title field.or.null
  sort.format.title
  *
  #1 entry.max$ substring$
  'sort.key$ :=
}


ITERATE {presort}

SORT            % by label, sort.label, title---for final label calculation

STRINGS { last.label next.extra }       % apalike labels are only for the text;

INTEGERS { last.extra.num }             % there are none in the bibliography

FUNCTION {initialize.extra.label.stuff} % and hence there is no `longest.label'
{ #0 int.to.chr$ 'last.label :=
  "" 'next.extra :=
  #0 'last.extra.num :=
}

FUNCTION {forward.pass}
{ last.label label =
    { last.extra.num #1 + 'last.extra.num :=
      last.extra.num int.to.chr$ 'extra.label :=
    }
    { "a" chr.to.int$ 'last.extra.num :=
      "" 'extra.label :=
      label 'last.label :=
    }
  if$
}

FUNCTION {reverse.pass}
{ next.extra "b" =
    { "a" 'extra.label := }
    'skip$
  if$
  label extra.label * 'label :=
  extra.label 'next.extra :=
}

EXECUTE {initialize.extra.label.stuff}

ITERATE {forward.pass}

REVERSE {reverse.pass}

%                               Now that the label is right we sort for real,
%                               on sort.label then year then title.  This is
%                               for the second sorting pass.
FUNCTION {bib.sort.order}
{ sort.label
  "    "
  *
  year field.or.null sortify
  *
  "    "
  *
  title field.or.null
  sort.format.title
  *
  #1 entry.max$ substring$
  'sort.key$ :=
}

ITERATE {bib.sort.order}

SORT            % by sort.label, year, title---giving final bibliography order

FUNCTION {begin.bib}
{ preamble$ empty$                              % no \etalchar in apalike
    'skip$
    { preamble$ write$ newline$ }
  if$
  "\begin{thebibliography}{}" write$ newline$           % no labels in apalike
}

EXECUTE {begin.bib}

EXECUTE {init.state.consts}

ITERATE {call.type$}

FUNCTION {end.bib}
{ newline$
  "\end{thebibliography}" write$ newline$
}

EXECUTE {end.bib}